请选择 进入手机版 | 继续访问电脑版

4Ameta

 找回密码
 立即注册
搜索
查看: 65|回复: 0

Learn x86 protected mode assembly language-c15.asm

[复制链接]

26

主题

26

帖子

119

积分

管理员

Rank: 9Rank: 9Rank: 9

积分
119
发表于 2022-9-12 21:14:13 | 显示全部楼层 |阅读模式
  1.          ;代码清单15-2
  2.          ;文件名:c15.asm
  3.          ;文件说明:用户程序
  4.          ;创建日期:2011-11-15 19:11   

  5. ;===============================================================================
  6. SECTION header vstart=0

  7.          program_length   dd program_end          ;程序总长度#0x00
  8.          
  9.          head_len         dd header_end           ;程序头部的长度#0x04

  10.          stack_seg        dd 0                    ;用于接收堆栈段选择子#0x08
  11.          stack_len        dd 1                    ;程序建议的堆栈大小#0x0c
  12.                                                   ;以4KB为单位
  13.                                                   
  14.          prgentry         dd start                ;程序入口#0x10
  15.          code_seg         dd section.code.start   ;代码段位置#0x14
  16.          code_len         dd code_end             ;代码段长度#0x18

  17.          data_seg         dd section.data.start   ;数据段位置#0x1c
  18.          data_len         dd data_end             ;数据段长度#0x20
  19. ;-------------------------------------------------------------------------------
  20.          ;符号地址检索表
  21.          salt_items       dd (header_end-salt)/256 ;#0x24
  22.          
  23.          salt:                                     ;#0x28
  24.          PrintString      db  '@PrintString'
  25.                      times 256-($-PrintString) db 0
  26.                      
  27.          TerminateProgram db  '@TerminateProgram'
  28.                      times 256-($-TerminateProgram) db 0
  29.                      
  30.          ReadDiskData     db  '@ReadDiskData'
  31.                      times 256-($-ReadDiskData) db 0
  32.                  
  33. header_end:
  34.   
  35. ;===============================================================================
  36. SECTION data vstart=0               

  37.          message_1        db  0x0d,0x0a
  38.                           db  '[USER TASK]: Hi! nice to meet you,'
  39.                           db  'I am run at CPL=',0
  40.                           
  41.          message_2        db  0
  42.                           db  '.Now,I must exit...',0x0d,0x0a,0

  43. data_end:

  44. ;===============================================================================
  45.       [bits 32]
  46. ;===============================================================================
  47. SECTION code vstart=0
  48. start:
  49.          ;任务启动时,DS指向头部段,也不需要设置堆栈
  50.          mov eax,ds
  51.          mov fs,eax
  52.      
  53.          mov eax,[data_seg]
  54.          mov ds,eax
  55.      
  56.          mov ebx,message_1
  57.          call far [fs:PrintString]
  58.          
  59.          mov ax,cs
  60.          and al,0000_0011B
  61.          or al,0x0030
  62.          mov [message_2],al
  63.          
  64.          mov ebx,message_2
  65.          call far [fs:PrintString]
  66.      
  67.          call far [fs:TerminateProgram]      ;退出,并将控制权返回到核心
  68.    
  69. code_end:

  70. ;-------------------------------------------------------------------------------
  71. SECTION trail
  72. ;-------------------------------------------------------------------------------
  73. program_end:
复制代码
  1.          ;代码清单15-1
  2.          ;文件名:c15_core.asm
  3.          ;文件说明:保护模式微型核心程序
  4.          ;创建日期:2011-11-19 21:40

  5.          ;以下常量定义部分。内核的大部分内容都应当固定
  6.          core_code_seg_sel     equ  0x38    ;内核代码段选择子
  7.          core_data_seg_sel     equ  0x30    ;内核数据段选择子
  8.          sys_routine_seg_sel   equ  0x28    ;系统公共例程代码段的选择子
  9.          video_ram_seg_sel     equ  0x20    ;视频显示缓冲区的段选择子
  10.          core_stack_seg_sel    equ  0x18    ;内核堆栈段选择子
  11.          mem_0_4_gb_seg_sel    equ  0x08    ;整个0-4GB内存的段的选择子

  12. ;-------------------------------------------------------------------------------
  13.          ;以下是系统核心的头部,用于加载核心程序
  14.          core_length      dd core_end       ;核心程序总长度#00

  15.          sys_routine_seg  dd section.sys_routine.start
  16.                                             ;系统公用例程段位置#04

  17.          core_data_seg    dd section.core_data.start
  18.                                             ;核心数据段位置#08

  19.          core_code_seg    dd section.core_code.start
  20.                                             ;核心代码段位置#0c


  21.          core_entry       dd start          ;核心代码段入口点#10
  22.                           dw core_code_seg_sel

  23. ;===============================================================================
  24.          [bits 32]
  25. ;===============================================================================
  26. SECTION sys_routine vstart=0                ;系统公共例程代码段
  27. ;-------------------------------------------------------------------------------
  28.          ;字符串显示例程
  29. put_string:                                 ;显示0终止的字符串并移动光标
  30.                                             ;输入:DS:EBX=串地址
  31.          push ecx
  32.   .getc:
  33.          mov cl,[ebx]
  34.          or cl,cl
  35.          jz .exit
  36.          call put_char
  37.          inc ebx
  38.          jmp .getc

  39.   .exit:
  40.          pop ecx
  41.          retf                               ;段间返回

  42. ;-------------------------------------------------------------------------------
  43. put_char:                                   ;在当前光标处显示一个字符,并推进
  44.                                             ;光标。仅用于段内调用
  45.                                             ;输入:CL=字符ASCII码
  46.          pushad

  47.          ;以下取当前光标位置
  48.          mov dx,0x3d4
  49.          mov al,0x0e
  50.          out dx,al
  51.          inc dx                             ;0x3d5
  52.          in al,dx                           ;高字
  53.          mov ah,al

  54.          dec dx                             ;0x3d4
  55.          mov al,0x0f
  56.          out dx,al
  57.          inc dx                             ;0x3d5
  58.          in al,dx                           ;低字
  59.          mov bx,ax                          ;BX=代表光标位置的16位数

  60.          cmp cl,0x0d                        ;回车符?
  61.          jnz .put_0a
  62.          mov ax,bx
  63.          mov bl,80
  64.          div bl
  65.          mul bl
  66.          mov bx,ax
  67.          jmp .set_cursor

  68.   .put_0a:
  69.          cmp cl,0x0a                        ;换行符?
  70.          jnz .put_other
  71.          add bx,80
  72.          jmp .roll_screen

  73.   .put_other:                               ;正常显示字符
  74.          push es
  75.          mov eax,video_ram_seg_sel          ;0xb8000段的选择子
  76.          mov es,eax
  77.          shl bx,1
  78.          mov [es:bx],cl
  79.          pop es

  80.          ;以下将光标位置推进一个字符
  81.          shr bx,1
  82.          inc bx

  83.   .roll_screen:
  84.          cmp bx,2000                        ;光标超出屏幕?滚屏
  85.          jl .set_cursor

  86.          push ds
  87.          push es
  88.          mov eax,video_ram_seg_sel
  89.          mov ds,eax
  90.          mov es,eax
  91.          cld
  92.          mov esi,0xa0                       ;小心!32位模式下movsb/w/d
  93.          mov edi,0x00                       ;使用的是esi/edi/ecx
  94.          mov ecx,1920
  95.          rep movsd
  96.          mov bx,3840                        ;清除屏幕最底一行
  97.          mov ecx,80                         ;32位程序应该使用ECX
  98.   .cls:
  99.          mov word[es:bx],0x0720
  100.          add bx,2
  101.          loop .cls

  102.          pop es
  103.          pop ds

  104.          mov bx,1920

  105.   .set_cursor:
  106.          mov dx,0x3d4
  107.          mov al,0x0e
  108.          out dx,al
  109.          inc dx                             ;0x3d5
  110.          mov al,bh
  111.          out dx,al
  112.          dec dx                             ;0x3d4
  113.          mov al,0x0f
  114.          out dx,al
  115.          inc dx                             ;0x3d5
  116.          mov al,bl
  117.          out dx,al

  118.          popad
  119.          
  120.          ret                                

  121. ;-------------------------------------------------------------------------------
  122. read_hard_disk_0:                           ;从硬盘读取一个逻辑扇区
  123.                                             ;EAX=逻辑扇区号
  124.                                             ;DS:EBX=目标缓冲区地址
  125.                                             ;返回:EBX=EBX+512
  126.          push eax
  127.          push ecx
  128.          push edx
  129.       
  130.          push eax
  131.          
  132.          mov dx,0x1f2
  133.          mov al,1
  134.          out dx,al                          ;读取的扇区数

  135.          inc dx                             ;0x1f3
  136.          pop eax
  137.          out dx,al                          ;LBA地址7~0

  138.          inc dx                             ;0x1f4
  139.          mov cl,8
  140.          shr eax,cl
  141.          out dx,al                          ;LBA地址15~8

  142.          inc dx                             ;0x1f5
  143.          shr eax,cl
  144.          out dx,al                          ;LBA地址23~16

  145.          inc dx                             ;0x1f6
  146.          shr eax,cl
  147.          or al,0xe0                         ;第一硬盘  LBA地址27~24
  148.          out dx,al

  149.          inc dx                             ;0x1f7
  150.          mov al,0x20                        ;读命令
  151.          out dx,al

  152.   .waits:
  153.          in al,dx
  154.          and al,0x88
  155.          cmp al,0x08
  156.          jnz .waits                         ;不忙,且硬盘已准备好数据传输

  157.          mov ecx,256                        ;总共要读取的字数
  158.          mov dx,0x1f0
  159.   .readw:
  160.          in ax,dx
  161.          mov [ebx],ax
  162.          add ebx,2
  163.          loop .readw

  164.          pop edx
  165.          pop ecx
  166.          pop eax
  167.       
  168.          retf                               ;段间返回

  169. ;-------------------------------------------------------------------------------
  170. ;汇编语言程序是极难一次成功,而且调试非常困难。这个例程可以提供帮助
  171. put_hex_dword:                              ;在当前光标处以十六进制形式显示
  172.                                             ;一个双字并推进光标
  173.                                             ;输入:EDX=要转换并显示的数字
  174.                                             ;输出:无
  175.          pushad
  176.          push ds
  177.       
  178.          mov ax,core_data_seg_sel           ;切换到核心数据段
  179.          mov ds,ax
  180.       
  181.          mov ebx,bin_hex                    ;指向核心数据段内的转换表
  182.          mov ecx,8
  183.   .xlt:   
  184.          rol edx,4
  185.          mov eax,edx
  186.          and eax,0x0000000f
  187.          xlat
  188.       
  189.          push ecx
  190.          mov cl,al                           
  191.          call put_char
  192.          pop ecx
  193.       
  194.          loop .xlt
  195.       
  196.          pop ds
  197.          popad
  198.          retf
  199.       
  200. ;-------------------------------------------------------------------------------
  201. allocate_memory:                            ;分配内存
  202.                                             ;输入:ECX=希望分配的字节数
  203.                                             ;输出:ECX=起始线性地址
  204.          push ds
  205.          push eax
  206.          push ebx
  207.       
  208.          mov eax,core_data_seg_sel
  209.          mov ds,eax
  210.       
  211.          mov eax,[ram_alloc]
  212.          add eax,ecx                        ;下一次分配时的起始地址
  213.       
  214.          ;这里应当有检测可用内存数量的指令
  215.          
  216.          mov ecx,[ram_alloc]                ;返回分配的起始地址

  217.          mov ebx,eax
  218.          and ebx,0xfffffffc
  219.          add ebx,4                          ;强制对齐
  220.          test eax,0x00000003                ;下次分配的起始地址最好是4字节对齐
  221.          cmovnz eax,ebx                     ;如果没有对齐,则强制对齐
  222.          mov [ram_alloc],eax                ;下次从该地址分配内存
  223.                                             ;cmovcc指令可以避免控制转移
  224.          pop ebx
  225.          pop eax
  226.          pop ds

  227.          retf

  228. ;-------------------------------------------------------------------------------
  229. set_up_gdt_descriptor:                      ;在GDT内安装一个新的描述符
  230.                                             ;输入:EDX:EAX=描述符
  231.                                             ;输出:CX=描述符的选择子
  232.          push eax
  233.          push ebx
  234.          push edx

  235.          push ds
  236.          push es

  237.          mov ebx,core_data_seg_sel          ;切换到核心数据段
  238.          mov ds,ebx

  239.          sgdt [pgdt]                        ;以便开始处理GDT

  240.          mov ebx,mem_0_4_gb_seg_sel
  241.          mov es,ebx

  242.          movzx ebx,word [pgdt]              ;GDT界限
  243.          inc bx                             ;GDT总字节数,也是下一个描述符偏移
  244.          add ebx,[pgdt+2]                   ;下一个描述符的线性地址

  245.          mov [es:ebx],eax
  246.          mov [es:ebx+4],edx

  247.          add word [pgdt],8                  ;增加一个描述符的大小

  248.          lgdt [pgdt]                        ;对GDT的更改生效

  249.          mov ax,[pgdt]                      ;得到GDT界限值
  250.          xor dx,dx
  251.          mov bx,8
  252.          div bx                             ;除以8,去掉余数
  253.          mov cx,ax
  254.          shl cx,3                           ;将索引号移到正确位置

  255.          pop es
  256.          pop ds

  257.          pop edx
  258.          pop ebx
  259.          pop eax

  260.          retf
  261. ;-------------------------------------------------------------------------------
  262. make_seg_descriptor:                        ;构造存储器和系统的段描述符
  263.                                             ;输入:EAX=线性基地址
  264.                                             ;      EBX=段界限
  265.                                             ;      ECX=属性。各属性位都在原始
  266.                                             ;          位置,无关的位清零
  267.                                             ;返回:EDX:EAX=描述符
  268.          mov edx,eax
  269.          shl eax,16
  270.          or ax,bx                           ;描述符前32位(EAX)构造完毕

  271.          and edx,0xffff0000                 ;清除基地址中无关的位
  272.          rol edx,8
  273.          bswap edx                          ;装配基址的31~24和23~16  (80486+)

  274.          xor bx,bx
  275.          or edx,ebx                         ;装配段界限的高4位

  276.          or edx,ecx                         ;装配属性

  277.          retf

  278. ;-------------------------------------------------------------------------------
  279. make_gate_descriptor:                       ;构造门的描述符(调用门等)
  280.                                             ;输入:EAX=门代码在段内偏移地址
  281.                                             ;       BX=门代码所在段的选择子
  282.                                             ;       CX=段类型及属性等(各属
  283.                                             ;          性位都在原始位置)
  284.                                             ;返回:EDX:EAX=完整的描述符
  285.          push ebx
  286.          push ecx
  287.       
  288.          mov edx,eax
  289.          and edx,0xffff0000                 ;得到偏移地址高16位
  290.          or dx,cx                           ;组装属性部分到EDX
  291.       
  292.          and eax,0x0000ffff                 ;得到偏移地址低16位
  293.          shl ebx,16                          
  294.          or eax,ebx                         ;组装段选择子部分
  295.       
  296.          pop ecx
  297.          pop ebx
  298.       
  299.          retf                                   
  300.                              
  301. ;-------------------------------------------------------------------------------
  302. terminate_current_task:                     ;终止当前任务
  303.                                             ;注意,执行此例程时,当前任务仍在
  304.                                             ;运行中。此例程其实也是当前任务的
  305.                                             ;一部分
  306.          pushfd
  307.          mov edx,[esp]                      ;获得EFLAGS寄存器内容
  308.          add esp,4                          ;恢复堆栈指针

  309.          mov eax,core_data_seg_sel
  310.          mov ds,eax

  311.          test dx,0100_0000_0000_0000B       ;测试NT位
  312.          jnz .b1                            ;当前任务是嵌套的,到.b1执行iretd
  313.          mov ebx,core_msg1                  ;当前任务不是嵌套的,直接切换到
  314.          call sys_routine_seg_sel:put_string
  315.          jmp far [prgman_tss]               ;程序管理器任务
  316.       
  317.   .b1:
  318.          mov ebx,core_msg0
  319.          call sys_routine_seg_sel:put_string
  320.          iretd
  321.       
  322. sys_routine_end:

  323. ;===============================================================================
  324. SECTION core_data vstart=0                  ;系统核心的数据段
  325. ;-------------------------------------------------------------------------------
  326.          pgdt             dw  0             ;用于设置和修改GDT
  327.                           dd  0

  328.          ram_alloc        dd  0x00100000    ;下次分配内存时的起始地址

  329.          ;符号地址检索表
  330.          salt:
  331.          salt_1           db  '@PrintString'
  332.                      times 256-($-salt_1) db 0
  333.                           dd  put_string
  334.                           dw  sys_routine_seg_sel

  335.          salt_2           db  '@ReadDiskData'
  336.                      times 256-($-salt_2) db 0
  337.                           dd  read_hard_disk_0
  338.                           dw  sys_routine_seg_sel

  339.          salt_3           db  '@PrintDwordAsHexString'
  340.                      times 256-($-salt_3) db 0
  341.                           dd  put_hex_dword
  342.                           dw  sys_routine_seg_sel

  343.          salt_4           db  '@TerminateProgram'
  344.                      times 256-($-salt_4) db 0
  345.                           dd  terminate_current_task
  346.                           dw  sys_routine_seg_sel

  347.          salt_item_len   equ $-salt_4
  348.          salt_items      equ ($-salt)/salt_item_len

  349.          message_1        db  '  If you seen this message,that means we '
  350.                           db  'are now in protect mode,and the system '
  351.                           db  'core is loaded,and the video display '
  352.                           db  'routine works perfectly.',0x0d,0x0a,0

  353.          message_2        db  '  System wide CALL-GATE mounted.',0x0d,0x0a,0
  354.          
  355.          bin_hex          db '0123456789ABCDEF'
  356.                                             ;put_hex_dword子过程用的查找表

  357.          core_buf   times 2048 db 0         ;内核用的缓冲区

  358.          cpu_brnd0        db 0x0d,0x0a,'  ',0
  359.          cpu_brand  times 52 db 0
  360.          cpu_brnd1        db 0x0d,0x0a,0x0d,0x0a,0

  361.          ;任务控制块链
  362.          tcb_chain        dd  0

  363.          ;程序管理器的任务信息
  364.          prgman_tss       dd  0             ;程序管理器的TSS基地址
  365.                           dw  0             ;程序管理器的TSS描述符选择子

  366.          prgman_msg1      db  0x0d,0x0a
  367.                           db  '[PROGRAM MANAGER]: Hello! I am Program Manager,'
  368.                           db  'run at CPL=0.Now,create user task and switch '
  369.                           db  'to it by the CALL instruction...',0x0d,0x0a,0
  370.                  
  371.          prgman_msg2      db  0x0d,0x0a
  372.                           db  '[PROGRAM MANAGER]: I am glad to regain control.'
  373.                           db  'Now,create another user task and switch to '
  374.                           db  'it by the JMP instruction...',0x0d,0x0a,0
  375.                  
  376.          prgman_msg3      db  0x0d,0x0a
  377.                           db  '[PROGRAM MANAGER]: I am gain control again,'
  378.                           db  'HALT...',0

  379.          core_msg0        db  0x0d,0x0a
  380.                           db  '[SYSTEM CORE]: Uh...This task initiated with '
  381.                           db  'CALL instruction or an exeception/ interrupt,'
  382.                           db  'should use IRETD instruction to switch back...'
  383.                           db  0x0d,0x0a,0

  384.          core_msg1        db  0x0d,0x0a
  385.                           db  '[SYSTEM CORE]: Uh...This task initiated with '
  386.                           db  'JMP instruction,  should switch to Program '
  387.                           db  'Manager directly by the JMP instruction...'
  388.                           db  0x0d,0x0a,0

  389. core_data_end:
  390.                
  391. ;===============================================================================
  392. SECTION core_code vstart=0
  393. ;-------------------------------------------------------------------------------
  394. fill_descriptor_in_ldt:                     ;在LDT内安装一个新的描述符
  395.                                             ;输入:EDX:EAX=描述符
  396.                                             ;          EBX=TCB基地址
  397.                                             ;输出:CX=描述符的选择子
  398.          push eax
  399.          push edx
  400.          push edi
  401.          push ds

  402.          mov ecx,mem_0_4_gb_seg_sel
  403.          mov ds,ecx

  404.          mov edi,[ebx+0x0c]                 ;获得LDT基地址
  405.          
  406.          xor ecx,ecx
  407.          mov cx,[ebx+0x0a]                  ;获得LDT界限
  408.          inc cx                             ;LDT的总字节数,即新描述符偏移地址
  409.          
  410.          mov [edi+ecx+0x00],eax
  411.          mov [edi+ecx+0x04],edx             ;安装描述符

  412.          add cx,8                           
  413.          dec cx                             ;得到新的LDT界限值

  414.          mov [ebx+0x0a],cx                  ;更新LDT界限值到TCB

  415.          mov ax,cx
  416.          xor dx,dx
  417.          mov cx,8
  418.          div cx
  419.          
  420.          mov cx,ax
  421.          shl cx,3                           ;左移3位,并且
  422.          or cx,0000_0000_0000_0100B         ;使TI位=1,指向LDT,最后使RPL=00

  423.          pop ds
  424.          pop edi
  425.          pop edx
  426.          pop eax
  427.      
  428.          ret
  429.          
  430. ;-------------------------------------------------------------------------------
  431. load_relocate_program:                      ;加载并重定位用户程序
  432.                                             ;输入: PUSH 逻辑扇区号
  433.                                             ;      PUSH 任务控制块基地址
  434.                                             ;输出:无
  435.          pushad
  436.       
  437.          push ds
  438.          push es
  439.       
  440.          mov ebp,esp                        ;为访问通过堆栈传递的参数做准备
  441.       
  442.          mov ecx,mem_0_4_gb_seg_sel
  443.          mov es,ecx
  444.       
  445.          mov esi,[ebp+11*4]                 ;从堆栈中取得TCB的基地址

  446.          ;以下申请创建LDT所需要的内存
  447.          mov ecx,160                        ;允许安装20个LDT描述符
  448.          call sys_routine_seg_sel:allocate_memory
  449.          mov [es:esi+0x0c],ecx              ;登记LDT基地址到TCB中
  450.          mov word [es:esi+0x0a],0xffff      ;登记LDT初始的界限到TCB中

  451.          ;以下开始加载用户程序
  452.          mov eax,core_data_seg_sel
  453.          mov ds,eax                         ;切换DS到内核数据段
  454.       
  455.          mov eax,[ebp+12*4]                 ;从堆栈中取出用户程序起始扇区号
  456.          mov ebx,core_buf                   ;读取程序头部数据     
  457.          call sys_routine_seg_sel:read_hard_disk_0

  458.          ;以下判断整个程序有多大
  459.          mov eax,[core_buf]                 ;程序尺寸
  460.          mov ebx,eax
  461.          and ebx,0xfffffe00                 ;使之512字节对齐(能被512整除的数低
  462.          add ebx,512                        ;9位都为0
  463.          test eax,0x000001ff                ;程序的大小正好是512的倍数吗?
  464.          cmovnz eax,ebx                     ;不是。使用凑整的结果
  465.       
  466.          mov ecx,eax                        ;实际需要申请的内存数量
  467.          call sys_routine_seg_sel:allocate_memory
  468.          mov [es:esi+0x06],ecx              ;登记程序加载基地址到TCB中
  469.       
  470.          mov ebx,ecx                        ;ebx -> 申请到的内存首地址
  471.          xor edx,edx
  472.          mov ecx,512
  473.          div ecx
  474.          mov ecx,eax                        ;总扇区数
  475.       
  476.          mov eax,mem_0_4_gb_seg_sel         ;切换DS到0-4GB的段
  477.          mov ds,eax

  478.          mov eax,[ebp+12*4]                 ;起始扇区号
  479.   .b1:
  480.          call sys_routine_seg_sel:read_hard_disk_0
  481.          inc eax
  482.          loop .b1                           ;循环读,直到读完整个用户程序

  483.          mov edi,[es:esi+0x06]              ;获得程序加载基地址

  484.          ;建立程序头部段描述符
  485.          mov eax,edi                        ;程序头部起始线性地址
  486.          mov ebx,[edi+0x04]                 ;段长度
  487.          dec ebx                            ;段界限
  488.          mov ecx,0x0040f200                 ;字节粒度的数据段描述符,特权级3
  489.          call sys_routine_seg_sel:make_seg_descriptor
  490.       
  491.          ;安装头部段描述符到LDT中
  492.          mov ebx,esi                        ;TCB的基地址
  493.          call fill_descriptor_in_ldt

  494.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  495.          mov [es:esi+0x44],cx               ;登记程序头部段选择子到TCB
  496.          mov [edi+0x04],cx                  ;和头部内
  497.       
  498.          ;建立程序代码段描述符
  499.          mov eax,edi
  500.          add eax,[edi+0x14]                 ;代码起始线性地址
  501.          mov ebx,[edi+0x18]                 ;段长度
  502.          dec ebx                            ;段界限
  503.          mov ecx,0x0040f800                 ;字节粒度的代码段描述符,特权级3
  504.          call sys_routine_seg_sel:make_seg_descriptor
  505.          mov ebx,esi                        ;TCB的基地址
  506.          call fill_descriptor_in_ldt
  507.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  508.          mov [edi+0x14],cx                  ;登记代码段选择子到头部

  509.          ;建立程序数据段描述符
  510.          mov eax,edi
  511.          add eax,[edi+0x1c]                 ;数据段起始线性地址
  512.          mov ebx,[edi+0x20]                 ;段长度
  513.          dec ebx                            ;段界限
  514.          mov ecx,0x0040f200                 ;字节粒度的数据段描述符,特权级3
  515.          call sys_routine_seg_sel:make_seg_descriptor
  516.          mov ebx,esi                        ;TCB的基地址
  517.          call fill_descriptor_in_ldt
  518.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  519.          mov [edi+0x1c],cx                  ;登记数据段选择子到头部

  520.          ;建立程序堆栈段描述符
  521.          mov ecx,[edi+0x0c]                 ;4KB的倍率
  522.          mov ebx,0x000fffff
  523.          sub ebx,ecx                        ;得到段界限
  524.          mov eax,4096                        
  525.          mul ecx                        
  526.          mov ecx,eax                        ;准备为堆栈分配内存
  527.          call sys_routine_seg_sel:allocate_memory
  528.          add eax,ecx                        ;得到堆栈的高端物理地址
  529.          mov ecx,0x00c0f600                 ;字节粒度的堆栈段描述符,特权级3
  530.          call sys_routine_seg_sel:make_seg_descriptor
  531.          mov ebx,esi                        ;TCB的基地址
  532.          call fill_descriptor_in_ldt
  533.          or cx,0000_0000_0000_0011B         ;设置选择子的特权级为3
  534.          mov [edi+0x08],cx                  ;登记堆栈段选择子到头部

  535.          ;重定位SALT
  536.          mov eax,mem_0_4_gb_seg_sel         ;这里和前一章不同,头部段描述符
  537.          mov es,eax                         ;已安装,但还没有生效,故只能通
  538.                                             ;过4GB段访问用户程序头部         
  539.          mov eax,core_data_seg_sel
  540.          mov ds,eax
  541.       
  542.          cld

  543.          mov ecx,[es:edi+0x24]              ;U-SALT条目数(通过访问4GB段取得)
  544.          add edi,0x28                       ;U-SALT在4GB段内的偏移
  545.   .b2:
  546.          push ecx
  547.          push edi
  548.       
  549.          mov ecx,salt_items
  550.          mov esi,salt
  551.   .b3:
  552.          push edi
  553.          push esi
  554.          push ecx

  555.          mov ecx,64                         ;检索表中,每条目的比较次数
  556.          repe cmpsd                         ;每次比较4字节
  557.          jnz .b4
  558.          mov eax,[esi]                      ;若匹配,则esi恰好指向其后的地址
  559.          mov [es:edi-256],eax               ;将字符串改写成偏移地址
  560.          mov ax,[esi+4]
  561.          or ax,0000000000000011B            ;以用户程序自己的特权级使用调用门
  562.                                             ;故RPL=3
  563.          mov [es:edi-252],ax                ;回填调用门选择子
  564.   .b4:
  565.       
  566.          pop ecx
  567.          pop esi
  568.          add esi,salt_item_len
  569.          pop edi                            ;从头比较
  570.          loop .b3
  571.       
  572.          pop edi
  573.          add edi,256
  574.          pop ecx
  575.          loop .b2

  576.          mov esi,[ebp+11*4]                 ;从堆栈中取得TCB的基地址

  577.          ;创建0特权级堆栈
  578.          mov ecx,4096
  579.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  580.          mov [es:esi+0x1a],ecx
  581.          shr dword [es:esi+0x1a],12         ;登记0特权级堆栈尺寸到TCB
  582.          call sys_routine_seg_sel:allocate_memory
  583.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  584.          mov [es:esi+0x1e],eax              ;登记0特权级堆栈基地址到TCB
  585.          mov ebx,0xffffe                    ;段长度(界限)
  586.          mov ecx,0x00c09600                 ;4KB粒度,读写,特权级0
  587.          call sys_routine_seg_sel:make_seg_descriptor
  588.          mov ebx,esi                        ;TCB的基地址
  589.          call fill_descriptor_in_ldt
  590.          ;or cx,0000_0000_0000_0000          ;设置选择子的特权级为0
  591.          mov [es:esi+0x22],cx               ;登记0特权级堆栈选择子到TCB
  592.          mov dword [es:esi+0x24],0          ;登记0特权级堆栈初始ESP到TCB
  593.       
  594.          ;创建1特权级堆栈
  595.          mov ecx,4096
  596.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  597.          mov [es:esi+0x28],ecx
  598.          shr [es:esi+0x28],12               ;登记1特权级堆栈尺寸到TCB
  599.          call sys_routine_seg_sel:allocate_memory
  600.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  601.          mov [es:esi+0x2c],eax              ;登记1特权级堆栈基地址到TCB
  602.          mov ebx,0xffffe                    ;段长度(界限)
  603.          mov ecx,0x00c0b600                 ;4KB粒度,读写,特权级1
  604.          call sys_routine_seg_sel:make_seg_descriptor
  605.          mov ebx,esi                        ;TCB的基地址
  606.          call fill_descriptor_in_ldt
  607.          or cx,0000_0000_0000_0001          ;设置选择子的特权级为1
  608.          mov [es:esi+0x30],cx               ;登记1特权级堆栈选择子到TCB
  609.          mov dword [es:esi+0x32],0          ;登记1特权级堆栈初始ESP到TCB

  610.          ;创建2特权级堆栈
  611.          mov ecx,4096
  612.          mov eax,ecx                        ;为生成堆栈高端地址做准备
  613.          mov [es:esi+0x36],ecx
  614.          shr [es:esi+0x36],12               ;登记2特权级堆栈尺寸到TCB
  615.          call sys_routine_seg_sel:allocate_memory
  616.          add eax,ecx                        ;堆栈必须使用高端地址为基地址
  617.          mov [es:esi+0x3a],ecx              ;登记2特权级堆栈基地址到TCB
  618.          mov ebx,0xffffe                    ;段长度(界限)
  619.          mov ecx,0x00c0d600                 ;4KB粒度,读写,特权级2
  620.          call sys_routine_seg_sel:make_seg_descriptor
  621.          mov ebx,esi                        ;TCB的基地址
  622.          call fill_descriptor_in_ldt
  623.          or cx,0000_0000_0000_0010          ;设置选择子的特权级为2
  624.          mov [es:esi+0x3e],cx               ;登记2特权级堆栈选择子到TCB
  625.          mov dword [es:esi+0x40],0          ;登记2特权级堆栈初始ESP到TCB
  626.       
  627.          ;在GDT中登记LDT描述符
  628.          mov eax,[es:esi+0x0c]              ;LDT的起始线性地址
  629.          movzx ebx,word [es:esi+0x0a]       ;LDT段界限
  630.          mov ecx,0x00408200                 ;LDT描述符,特权级0
  631.          call sys_routine_seg_sel:make_seg_descriptor
  632.          call sys_routine_seg_sel:set_up_gdt_descriptor
  633.          mov [es:esi+0x10],cx               ;登记LDT选择子到TCB中
  634.       
  635.          ;创建用户程序的TSS
  636.          mov ecx,104                        ;tss的基本尺寸
  637.          mov [es:esi+0x12],cx              
  638.          dec word [es:esi+0x12]             ;登记TSS界限值到TCB
  639.          call sys_routine_seg_sel:allocate_memory
  640.          mov [es:esi+0x14],ecx              ;登记TSS基地址到TCB
  641.       
  642.          ;登记基本的TSS表格内容
  643.          mov word [es:ecx+0],0              ;反向链=0
  644.       
  645.          mov edx,[es:esi+0x24]              ;登记0特权级堆栈初始ESP
  646.          mov [es:ecx+4],edx                 ;到TSS中
  647.       
  648.          mov dx,[es:esi+0x22]               ;登记0特权级堆栈段选择子
  649.          mov [es:ecx+8],dx                  ;到TSS中
  650.       
  651.          mov edx,[es:esi+0x32]              ;登记1特权级堆栈初始ESP
  652.          mov [es:ecx+12],edx                ;到TSS中

  653.          mov dx,[es:esi+0x30]               ;登记1特权级堆栈段选择子
  654.          mov [es:ecx+16],dx                 ;到TSS中

  655.          mov edx,[es:esi+0x40]              ;登记2特权级堆栈初始ESP
  656.          mov [es:ecx+20],edx                ;到TSS中

  657.          mov dx,[es:esi+0x3e]               ;登记2特权级堆栈段选择子
  658.          mov [es:ecx+24],dx                 ;到TSS中

  659.          mov dx,[es:esi+0x10]               ;登记任务的LDT选择子
  660.          mov [es:ecx+96],dx                 ;到TSS中
  661.       
  662.          mov dx,[es:esi+0x12]               ;登记任务的I/O位图偏移
  663.          mov [es:ecx+102],dx                ;到TSS中
  664.       
  665.          mov word [es:ecx+100],0            ;T=0
  666.       
  667.          mov dword [es:ecx+28],0            ;登记CR3(PDBR)
  668.       
  669.          ;访问用户程序头部,获取数据填充TSS
  670.          mov ebx,[ebp+11*4]                 ;从堆栈中取得TCB的基地址
  671.          mov edi,[es:ebx+0x06]              ;用户程序加载的基地址

  672.          mov edx,[es:edi+0x10]              ;登记程序入口点(EIP)
  673.          mov [es:ecx+32],edx                ;到TSS

  674.          mov dx,[es:edi+0x14]               ;登记程序代码段(CS)选择子
  675.          mov [es:ecx+76],dx                 ;到TSS中

  676.          mov dx,[es:edi+0x08]               ;登记程序堆栈段(SS)选择子
  677.          mov [es:ecx+80],dx                 ;到TSS中

  678.          mov dx,[es:edi+0x04]               ;登记程序数据段(DS)选择子
  679.          mov word [es:ecx+84],dx            ;到TSS中。注意,它指向程序头部段
  680.       
  681.          mov word [es:ecx+72],0             ;TSS中的ES=0

  682.          mov word [es:ecx+88],0             ;TSS中的FS=0

  683.          mov word [es:ecx+92],0             ;TSS中的GS=0

  684.          pushfd
  685.          pop edx
  686.          
  687.          mov dword [es:ecx+36],edx          ;EFLAGS

  688.          ;在GDT中登记TSS描述符
  689.          mov eax,[es:esi+0x14]              ;TSS的起始线性地址
  690.          movzx ebx,word [es:esi+0x12]       ;段长度(界限)
  691.          mov ecx,0x00408900                 ;TSS描述符,特权级0
  692.          call sys_routine_seg_sel:make_seg_descriptor
  693.          call sys_routine_seg_sel:set_up_gdt_descriptor
  694.          mov [es:esi+0x18],cx               ;登记TSS选择子到TCB

  695.          pop es                             ;恢复到调用此过程前的es段
  696.          pop ds                             ;恢复到调用此过程前的ds段
  697.       
  698.          popad
  699.       
  700.          ret 8                              ;丢弃调用本过程前压入的参数
  701.       
  702. ;-------------------------------------------------------------------------------
  703. append_to_tcb_link:                         ;在TCB链上追加任务控制块
  704.                                             ;输入:ECX=TCB线性基地址
  705.          push eax
  706.          push edx
  707.          push ds
  708.          push es
  709.          
  710.          mov eax,core_data_seg_sel          ;令DS指向内核数据段
  711.          mov ds,eax
  712.          mov eax,mem_0_4_gb_seg_sel         ;令ES指向0..4GB段
  713.          mov es,eax
  714.          
  715.          mov dword [es: ecx+0x00],0         ;当前TCB指针域清零,以指示这是最
  716.                                             ;后一个TCB
  717.                                              
  718.          mov eax,[tcb_chain]                ;TCB表头指针
  719.          or eax,eax                         ;链表为空?
  720.          jz .notcb
  721.          
  722.   .searc:
  723.          mov edx,eax
  724.          mov eax,[es: edx+0x00]
  725.          or eax,eax               
  726.          jnz .searc
  727.          
  728.          mov [es: edx+0x00],ecx
  729.          jmp .retpc
  730.          
  731.   .notcb:      
  732.          mov [tcb_chain],ecx                ;若为空表,直接令表头指针指向TCB
  733.          
  734.   .retpc:
  735.          pop es
  736.          pop ds
  737.          pop edx
  738.          pop eax
  739.          
  740.          ret
  741.          
  742. ;-------------------------------------------------------------------------------
  743. start:
  744.          mov ecx,core_data_seg_sel          ;令DS指向核心数据段
  745.          mov ds,ecx

  746.          mov ecx,mem_0_4_gb_seg_sel         ;令ES指向4GB数据段
  747.          mov es,ecx

  748.          mov ebx,message_1                    
  749.          call sys_routine_seg_sel:put_string
  750.                                          
  751.          ;显示处理器品牌信息
  752.          mov eax,0x80000002
  753.          cpuid
  754.          mov [cpu_brand + 0x00],eax
  755.          mov [cpu_brand + 0x04],ebx
  756.          mov [cpu_brand + 0x08],ecx
  757.          mov [cpu_brand + 0x0c],edx
  758.       
  759.          mov eax,0x80000003
  760.          cpuid
  761.          mov [cpu_brand + 0x10],eax
  762.          mov [cpu_brand + 0x14],ebx
  763.          mov [cpu_brand + 0x18],ecx
  764.          mov [cpu_brand + 0x1c],edx

  765.          mov eax,0x80000004
  766.          cpuid
  767.          mov [cpu_brand + 0x20],eax
  768.          mov [cpu_brand + 0x24],ebx
  769.          mov [cpu_brand + 0x28],ecx
  770.          mov [cpu_brand + 0x2c],edx

  771.          mov ebx,cpu_brnd0                  ;显示处理器品牌信息
  772.          call sys_routine_seg_sel:put_string
  773.          mov ebx,cpu_brand
  774.          call sys_routine_seg_sel:put_string
  775.          mov ebx,cpu_brnd1
  776.          call sys_routine_seg_sel:put_string

  777.          ;以下开始安装为整个系统服务的调用门。特权级之间的控制转移必须使用门
  778.          mov edi,salt                       ;C-SALT表的起始位置
  779.          mov ecx,salt_items                 ;C-SALT表的条目数量
  780.   .b3:
  781.          push ecx   
  782.          mov eax,[edi+256]                  ;该条目入口点的32位偏移地址
  783.          mov bx,[edi+260]                   ;该条目入口点的段选择子
  784.          mov cx,1_11_0_1100_000_00000B      ;特权级3的调用门(3以上的特权级才
  785.                                             ;允许访问),0个参数(因为用寄存器
  786.                                             ;传递参数,而没有用栈)
  787.          call sys_routine_seg_sel:make_gate_descriptor
  788.          call sys_routine_seg_sel:set_up_gdt_descriptor
  789.          mov [edi+260],cx                   ;将返回的门描述符选择子回填
  790.          add edi,salt_item_len              ;指向下一个C-SALT条目
  791.          pop ecx
  792.          loop .b3

  793.          ;对门进行测试
  794.          mov ebx,message_2
  795.          call far [salt_1+256]              ;通过门显示信息(偏移量将被忽略)
  796.       
  797.          ;为程序管理器的TSS分配内存空间
  798.          mov ecx,104                        ;为该任务的TSS分配内存
  799.          call sys_routine_seg_sel:allocate_memory
  800.          mov [prgman_tss+0x00],ecx          ;保存程序管理器的TSS基地址
  801.       
  802.          ;在程序管理器的TSS中设置必要的项目
  803.          mov word [es:ecx+96],0             ;没有LDT。处理器允许没有LDT的任务。
  804.          mov word [es:ecx+102],103          ;没有I/O位图。0特权级事实上不需要。
  805.          mov word [es:ecx+0],0              ;反向链=0
  806.          mov dword [es:ecx+28],0            ;登记CR3(PDBR)
  807.          mov word [es:ecx+100],0            ;T=0
  808.                                             ;不需要0、1、2特权级堆栈。0特级不
  809.                                             ;会向低特权级转移控制。
  810.          
  811.          ;创建TSS描述符,并安装到GDT中
  812.          mov eax,ecx                        ;TSS的起始线性地址
  813.          mov ebx,103                        ;段长度(界限)
  814.          mov ecx,0x00408900                 ;TSS描述符,特权级0
  815.          call sys_routine_seg_sel:make_seg_descriptor
  816.          call sys_routine_seg_sel:set_up_gdt_descriptor
  817.          mov [prgman_tss+0x04],cx           ;保存程序管理器的TSS描述符选择子

  818.          ;任务寄存器TR中的内容是任务存在的标志,该内容也决定了当前任务是谁。
  819.          ;下面的指令为当前正在执行的0特权级任务“程序管理器”后补手续(TSS)。
  820.          ltr cx                              

  821.          ;现在可认为“程序管理器”任务正执行中
  822.          mov ebx,prgman_msg1
  823.          call sys_routine_seg_sel:put_string

  824.          mov ecx,0x46
  825.          call sys_routine_seg_sel:allocate_memory
  826.          call append_to_tcb_link            ;将此TCB添加到TCB链中
  827.       
  828.          push dword 50                      ;用户程序位于逻辑50扇区
  829.          push ecx                           ;压入任务控制块起始线性地址
  830.       
  831.          call load_relocate_program         
  832.       
  833.          call far [es:ecx+0x14]             ;执行任务切换。和上一章不同,任务切
  834.                                             ;换时要恢复TSS内容,所以在创建任务
  835.                                             ;时TSS要填写完整
  836.                                           
  837.          ;重新加载并切换任务
  838.          mov ebx,prgman_msg2
  839.          call sys_routine_seg_sel:put_string

  840.          mov ecx,0x46
  841.          call sys_routine_seg_sel:allocate_memory
  842.          call append_to_tcb_link            ;将此TCB添加到TCB链中

  843.          push dword 50                      ;用户程序位于逻辑50扇区
  844.          push ecx                           ;压入任务控制块起始线性地址

  845.          call load_relocate_program

  846.          jmp far [es:ecx+0x14]              ;执行任务切换

  847.          mov ebx,prgman_msg3
  848.          call sys_routine_seg_sel:put_string

  849.          hlt
  850.             
  851. core_code_end:

  852. ;-------------------------------------------------------------------------------
  853. SECTION core_trail
  854. ;-------------------------------------------------------------------------------
  855. core_end:
复制代码

回复

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

Archiver|手机版|小黑屋|4ameta

GMT+8, 2022-10-2 23:34 , Processed in 0.041352 second(s), 17 queries .

Powered by Discuz! X3.4

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表